查看SKU:RB-02S020A DS18B20數(shù)字溫度傳感器的源代碼

<br/>
[[文件:02S020A01.jpg|500px|有框|右]]
==產品概述==
最新推出的DS18B20數(shù)字溫度傳感器采用美國DALLAS公司生產的DS18B20一總線數(shù)字溫度感測元件其測溫范圍 －55℃～＋125℃，固有測溫分辨率0.5℃，支持多點組網功能，多個DS18B20可以并聯(lián)在唯一的三線上，實現(xiàn)多點測溫，測量結果以9~12位數(shù)字量方式串行傳送。 DS18B20數(shù)字溫度傳感器可在各種單片機控制器上應用，尤其在Arduino控制器上更為簡單，現(xiàn)成庫函數(shù)調用，即可完成溫度測量，通過3P傳感器連接線插接到Arduino專用傳感器擴展板上，可以非常容易地實現(xiàn)與環(huán)境溫度感知相關的互動作品。
==規(guī)格參數(shù)==
# 類型：數(shù)字模塊（一總線接口）
# 可用于檢測周圍空氣溫度
# 溫度測量范圍：－55℃～＋125℃
# 測量精度：±0.5 °C（-10 °C至+85 °C范圍內）
# 9位～12位A/D轉換精度
# 分辨率：0.5℃
# 供電電壓：3.3V或5V
8. 產品尺寸圖：<br/>
[[文件:size026.jpg|500px|縮略圖|居中]]

9.接口定義<br/>
:S：輸出信號
:+：電源(VCC)
:-：地(GND)

==工作原理==
DS18B20 是一款常用的數(shù)字溫度傳感器，DS18B20 主要由 64 位光刻 ROM、溫度傳感器、非揮發(fā)的溫度報警觸發(fā)器 TH 和 TL、配置寄存器等四部分組成，具有體積小，使用方便，抗干擾能力強，精度高等特點，適用于各種狹小空間數(shù)字測溫和控制領域。<br/>
DS18B20 提供9位（二進制）溫度讀數(shù)來表示所測的溫度值，采用單線接口，使用時，僅需要一條口線即可實現(xiàn)與單片機的雙向通信，簡化了分布式溫度傳感器的應用。在使用中不需要任何外圍元件，且支持多點組網的功能，多個 DS18B20 可以并聯(lián)在唯一的三線上，最多可并聯(lián)8個，實現(xiàn)多點測溫。溫度測量范圍是 -55 - +125℃，固有測溫分辨率為 ±0.5℃，可在 1 秒內把溫度變換成數(shù)字信號輸出。<br/>
DS18B20 有兩種供電方式，即數(shù)據(jù)總線供電方式與外部供電方式，采用數(shù)據(jù)總線供電雖然可以節(jié)省一根導線，但完成溫度測量的時間較長；采取外部供電方式雖然多用了一根導線，但是測量速度較快，可以根據(jù)實際需求選擇供電方式。<br/> 

==編程原理==
數(shù)字溫度傳感器模塊引出三個接口，包含有數(shù)據(jù)線 S，電源 Vcc 和地線 GND，實際應用時，可以將數(shù)據(jù)線 S 端與 Arduino 控制器的數(shù)字引腳連接，如 D2，Arduino 專門提供了可供調用的庫函數(shù)，該函數(shù)的文件名分別為 DallasTemperature 和 OneWire，。通過分別在程序中引用 DallasTemperature.h 和 OneWire.h，并分別實例化對象 OneWire 和 Sensor 類，直接使用類的成員函數(shù)來實現(xiàn)數(shù)字傳感器的溫度采集。

==使用方法==
===example1_Arduino===
*主要硬件
:Arduino UNO 控制器
:傳感器擴展板V5.0
:DS18B20 溫度傳感器模塊
:通用3P傳感器連接線 
:USB 數(shù)據(jù)通信線 

* 硬件連接
[[文件:02S020A100.png|700px|有框|居中]]

* 例子程序
<pre style='color:blue'>
#include <OneWire.h>
#include <DallasTemperature.h>
 
// 定義DS18B20數(shù)據(jù)口連接arduino的2號IO上
#define ONE_WIRE_BUS 2
 
// 初始連接在單總線上的單總線設備
OneWire oneWire(ONE_WIRE_BUS);
DallasTemperature sensors(&oneWire);
 
void setup(void)
{
  // 設置串口通信波特率
  Serial.begin(9600);
  Serial.println("Dallas Temperature IC Control Library Demo");
 
  // 初始庫
  sensors.begin();
}
 
void loop(void)
{ 
  Serial.print("Requesting temperatures...");
  sensors.requestTemperatures(); // 發(fā)送命令獲取溫度
  Serial.println("DONE");
   
  Serial.print("Temperature for the device 1 (index 0) is: ");
  Serial.println(sensors.getTempCByIndex(0));  
}
 </pre>
* 程序效果
[[文件:02S020A03.png|500px|有框|居中]]

===example2_Arduino===
*主要硬件
:Arduino UNO 控制器
:傳感器擴展板V5.0
:DS18B20 溫度傳感器模塊
:通用3P傳感器連接線 
:USB 數(shù)據(jù)通信線 

* 硬件連接
[[文件:02S020A101.png|700px|有框|居中]]

* 例子程序
<pre style='color:blue'>
#include <OneWire.h>
OneWire  ds(10);  // 連接arduino10引腳
void setup(void) {
  Serial.begin(9600);
}
void loop(void) {
  byte i;
  byte present = 0;
  byte type_s;
  byte data[12];
  byte addr[8];
  float celsius, fahrenheit;  
  if ( !ds.search(addr)) {
    Serial.println("No more addresses.");
    Serial.println();
    ds.reset_search();
    delay(250);
    return;
  }  
  Serial.print("ROM =");
  for( i = 0; i < 8; i++) {
    Serial.write(' ');
    Serial.print(addr[i], HEX);
  }
 
  if (OneWire::crc8(addr, 7) != addr[7]) {
      Serial.println("CRC is not valid!");
      return;
  }
  Serial.println();
  
  // the first ROM byte indicates which chip
  switch (addr[0]) {
    case 0x10:
      Serial.println("  Chip = DS18S20");  // or old DS1820
      type_s = 1;
      break;
    case 0x28:
      Serial.println("  Chip = DS18B20");
      type_s = 0;
      break;
    case 0x22:
      Serial.println("  Chip = DS1822");
      type_s = 0;
      break;
    default:
      Serial.println("Device is not a DS18x20 family device.");
      return;
  } 
 
  ds.reset();
  ds.select(addr);
  ds.write(0x44,1);         // start conversion, with parasite power on at the end
   
  delay(1000);     // maybe 750ms is enough, maybe not
  // we might do a ds.depower() here, but the reset will take care of it.
   
  present = ds.reset();
  ds.select(addr);    
  ds.write(0xBE);         // Read Scratchpad
 
  Serial.print("  Data = ");
  Serial.print(present,HEX);
  Serial.print(" ");
  for ( i = 0; i < 9; i++) {           // we need 9 bytes
    data[i] = ds.read();
    Serial.print(data[i], HEX);
    Serial.print(" ");
  }
  Serial.print(" CRC=");
  Serial.print(OneWire::crc8(data, 8), HEX);
  Serial.println();
  // convert the data to actual temperature
  unsigned int raw = (data[1] << 8) | data[0];
  if (type_s) {
    raw = raw << 3; // 9 bit resolution default
    if (data[7] == 0x10) {
      // count remain gives full 12 bit resolution
      raw = (raw & 0xFFF0) + 12 - data[6];
    }
  } else {
    byte cfg = (data[4] & 0x60);
    if (cfg == 0x00) raw = raw << 3;  // 9 bit resolution, 93.75 ms
    else if (cfg == 0x20) raw = raw << 2; // 10 bit res, 187.5 ms
    else if (cfg == 0x40) raw = raw << 1; // 11 bit res, 375 ms
    // default is 12 bit resolution, 750 ms conversion time
  }
  celsius = (float)raw / 16.0;
  fahrenheit = celsius * 1.8 + 32.0;
  Serial.print("  Temperature = ");
  Serial.print(celsius);
  Serial.print(" Celsius, ");   
  Serial.print(fahrenheit);
  Serial.println(" Fahrenheit");
}
 </pre>

* 程序效果
[[文件:02S020A04.png|500px|有框|居中]]

==應用視頻==
[[File:wen du 01.png|400px|左|link=http://v.youku.com/v_show/id_XODg0ODMzNzAw.html?from=y1.7-2]]
[[File:wen du 02.png|400px|居中|link=http://v.youku.com/v_show/id_XNDkxNjQ2NDAw.html?from=y1.7-2]]
<br/>
==產品相關推薦==
[[文件:erweima.png|230px|無框|右]]
===資料下載===
網盤鏈接： https://pan.baidu.com/s/1jTDC5TGtImxm29o0HOtwrw 
提取碼：t8vz
===購買地址===
[http://www.gharee.com/goods-161.html  DS18B20 數(shù)字溫度傳感器]<br/>
===周邊產品推薦===
[http://www.gharee.com/goods-72.html Arduino DHT11 溫度傳感器]
<br/>
[http://www.gharee.com/goods-71.html LM35 線性溫度傳感器 ]<br/>
[http://www.gharee.com/goods.php?id=46 土壤濕度傳感器 ]
===相關問題解答===
[http://www.makerspace.cn/forum.php?mod=viewthread&tid=4240&fromuid=10780 DS18B20 數(shù)字溫度傳感器數(shù)據(jù)波動異常]
===相關學習資料===
[http://www.makerspace.cn/forum.php?mod=viewthread&tid=5339&fromuid=10780 Adafruit 的樹莓派教程 DS18B20溫度傳感器]<br/>
[http://www.makerspace.cn/portal.php 奧松機器人技術論壇]